Access XBOX file system via Windows Explorer

[clabs]

Hi folks

I am the lucky new owner of a couple of N64 freaks 1.0Ghz 128Mb motherboards. These have gone into boxes with 1.5tb drives that are pretty much crammed full of games, emulators etc. Now - I have the fairly monumental task of patching all the XBEs so the games run at the correct speed.

I do have a patcher programme that will patch individual XBEs which is pretty slow going but yesterday, I came across a similar Patcher that searches through directories and batch patches all the XBEs that it finds which is a step in the right direction. Of course, this is a Windows programme so as things stand, I still have to FTP the various directories back to my PC, run the Patcher, then FTP back again. I am trying to remove the FTP step if possible.

So, my question is, is it possible to access the XBOX file system via Windows Explorer? I spent a good amount of time searching for a solution but everything I find covers setting up a share on a pc to make those files available to the Xbox and I cannot find a way to do it the other way around, if that makes sense!

Am I missing a trick here or is what I am trying to achieve simply not possible?

If anyone has any suggestions then that would be great.

Cheers

[Spongy]

ftp://user:pass@xbox.ip.address

Mine is ftp://xbox:xbox@192.168.1.10

[Dan Dar3]

If My Computer > "Network locations" will do for your application, here's how you can add to Network locations:
http://support.microsoft.com/kb/308416
http://windows.microsoft.com/en-ie/wind ... work-drive

[clabs]

Thanks for the pointers, Dan & Spongy - very helpful.

OK - I only can "browse" to the xbox via ftp://xbox:xbox@ipaddress. I can also add this as a saved network location but it cannot be mapped in the true sense that it cannot be allocated a drive letter. (Windows 7 BTW)

Irritatingly, this means that it does not appear under network drives when I browse for it via the patcher programme.

It is looking like what I want to achieve is not possible and the resources I am putting into this would be better spent with some FTP time

Cheers again for your help guys.

[Spongy]

If you have network shares setup (movies, music, etc.) you could use file manager to push the files to that share.

[clabs]

Thanks for the suggestion Spongy - appreciate it mate. Unfortunately though, if I have to move stuff around then I may as well FTP it.

Any - this evening I found a solution that worked really well for me

I downloaded a bit of software called WebDrive (21 day free trial). This allows you to allocate a drive letter to an FTP location in Windows 7 which IS recognised by the bulk Patcher utility. This allowed me to patch just shy of 900 XBEs in about 45 minutes with very little intervention from me. Lord knows how long that would have taken me to do it manually.

Here is the patcher that I used - might well come in handy for someone. My thanks to the author Mwaterbu over at emuextras.

XBEPatcher.7z

(13.25 KiB) Downloaded 237 times

[SPPV]

You could try an oldschool but handy method. Write a batch with "start FTP:\Your XBOX address " start "exe name and location" (aka the renamer)and click it. It should work. All these apps like encoders and renamers use CMD32 they may have used NSIS to make it look fancy but end of day its CMD32

[Rocky5]

Here is a free alternative to webdrive & any application will see the ftp drive as if it were a HDD.

Ftpuse
http://www.ferrobackup.com/ftpuse/

the above doesn't work on window 8 so had to get WebDrive & its cracking, can backup all my XBE files in a few mins!

here is the batch file to do so. ( it will only download the latest/newer files so saves on time first run though it will download all files specified )

Code: Select all

@Echo off & SetLocal EnableDelayedExpansion & mode con:cols=56 lines=15 & Title Download xbe files

:: Directories
Set "Games_Location=X:\G\Games"
Set "Output_Folder=Game xbe's"

:: Files to download
Set "File1=default.xbe"
Set "File2=thumb.jpg"
Set "File3=fanart.jpg"
Set "File4=default.tbn"
Set "File5="

:: Code
cls
Echo:
Echo:
Echo  About to download
Echo:
if not "%File1%"=="" Echo  1) %File1%
if not "%File2%"=="" Echo  2) %File2%
if not "%File3%"=="" Echo  3) %File3%
if not "%File4%"=="" Echo  4) %File4%
if not "%File5%"=="" Echo  5) %File5%
Echo:
Echo  This can take some time depending on the
Echo  number of games.
timeout /t 5 >NUL & cls

::dir /b "X:\G\Games">>list.txt

if not exist "%Output_Folder%" MD "%Output_Folder%"

for /f "tokens=*" %%a in ('dir /b /on "%Games_Location%"') do (
Echo:
Echo  %%a
Echo:
if not "%File1%"=="" xcopy /I /Y /D /J "%Games_Location%\%%a\%File1%" "%Output_Folder%\%%a\"
if not "%File2%"=="" xcopy /I /Y /D /J "%Games_Location%\%%a\%File2%" "%Output_Folder%\%%a\"
if not "%File3%"=="" xcopy /I /Y /D /J "%Games_Location%\%%a\%File3%" "%Output_Folder%\%%a\"
if not "%File4%"=="" xcopy /I /Y /D /J "%Games_Location%\%%a\%File4%" "%Output_Folder%\%%a\"
if not "%File5%"=="" xcopy /I /Y /D /J "%Games_Location%\%%a\%File5%" "%Output_Folder%\%%a\"
Echo:
cls
)

Here is another to backup C/E/F/G & clean any unused TDATA/UDATA folders. ( each location can be set true (1) or false (0), same as above it will download only new/updated files )

Code: Select all

@Echo off & SetLocal EnableDelayedExpansion & mode con:cols=56 lines=15 & Title Backup Xbox Partitions

CD %~dp0

:: 1 = true / 0 = false
Set "Backup_C=1"
Set "Backup_E=1"
Set "Backup_F=1"
Set "Backup_G=0"

:: Directories
Set "Location1=X:\C"
Set "Location2=X:\E"
Set "Location3=X:\F"
Set "Location4=X:\G"
Set "Output_Folder1=C"
Set "Output_Folder2=E"
Set "Output_Folder3=F"
Set "Output_Folder4=G"

:: Code
cls
Echo:
Echo:
Echo  About to Backup
Echo:
if "%Backup_C%"=="1" Echo  1) %Output_Folder1%
if "%Backup_E%"=="1" Echo  2) %Output_Folder2%
if "%Backup_F%"=="1" Echo  3) %Output_Folder3%
if "%Backup_G%"=="1" Echo  4) %Output_Folder4%
Echo:
Echo  This can take some time.
Echo:
timeout /t 5 >NUL & cls

if "%Backup_C%"=="1" (
MD "%Output_Folder1%" 2>NUL
Echo:
if "%Backup_C%"=="1" xcopy /S /E /I /Y /D /J "%Location1%" "%Output_Folder1%"
Echo:
cls
)

if "%Backup_E%"=="1" (
MD "%Output_Folder2%" 2>NUL
Echo:
if "%Backup_E%"=="1" xcopy /S /E /I /Y /D /J "%Location2%" "%Output_Folder2%"
Echo:
cls
)

if "%Backup_F%"=="1" (
MD "%Output_Folder3%" 2>NUL
Echo:
if "%Backup_F%"=="1" xcopy /S /E /I /Y /D /J "%Location3%" "%Output_Folder3%"
Echo:
cls
)

if "%Backup_G%"=="1" (
MD "%Output_Folder4%" 2>NUL
Echo:
if "%Backup_G%"=="1" xcopy /S /E /I /Y /D /J "%Location4%" "%Output_Folder4%"
Echo:
cls
)


:: Remove empty folders from TDAtA & UDATA
CD "E\TDATA\"

for /f "delims=" %%d in ('dir /s /b /ad ^| sort /r') do rd "%%d"

CD %~dp0

CD "E\UDATA\"

MD Check
for /f "delims=" %%d in ('dir /b "*"') do xcopy /S /I /Y %%d "Check\%%d" 
CD "Check"
del /q /s "SaveImage.xbx"
del /q /s "TitleImage.xbx"
del /q /s "TitleMeta.xbx"
for /f "delims=" %%d in ('dir /s /b /ad ^| sort /r') do rd "%%d"
for /f "delims=" %%d in ('dir /b /ad "*"') do Echo %%d>>..\List.txt
CD ..\
md "..\Not Empty"
for /f "delims=" %%d in (list.txt) do move "%%d" "..\Not Empty"
copy "*.profile" "..\Not Empty"
copy "NICKNAME.XBN" "..\Not Empty"
CD ..\
rd /q /s "UDATA"
ren "Not Empty" "UDATA"

[clabs]

Hey Rocky.

I did find and try FTPuse before I found Webdrive but I found it unfriendly and didn't get it to work on W7. Webdrive was up and running in a few minutes.

Anyway, glad it works well for you and thanks for the scripts bud - appreciate it